QML: tutor de vistas
EL objetivo de estos tutoriales es familiarizarse con la integración de objetos Lista QML en nuestras aplicaciones.
Todos los objetos de ambos ejemplos de este tutor los encontraremos en la carpeta tutores/qml/qml vistas del proyecto de aplicación de vTutor.
En este tutorial veremos las tres vistas básicas para mostrar elementos de un modelo, integrado con la base de datos de Velneo. Las vistas nos permiten posicionar y definir cómo se mostrarán los elementos de un modelo, en este caso registros provenientes de la base de datos de Velneo.
ListView
GridView
El componente ListView de QML nos permite mostrar en una vista en forma de lista los elementos de un modelo. Se trata de un posicionador para elementos de un modelo, define cómo se pintan éstos.
En este ejemplo, el modelo lo proporciona Velneo a partir de una tabla ART_M y se mostrará por cada elemento cierta información y una imagen.
El objeto QML permite definir dos elementos estándar para mostrar la información en QML, Contenido y URL imagen, que en el código QML se indican con las etiquetas display y decoration respectivamente.
Para incluir más información hacemos uso de los UserRoles, que permiten definir tantas etiquetas como queramos, y que se definen como una fórmula que puede hacer uso de campos, funciones, etc. En este caso, y sólo como ejemplo, hemos creado dos, fecha y hora que mostrarán el dato actual haciendo uso de las funciones correspondientes.
Comenzamos con la declaración de la importación de QtQuick 1.0, ya que usaremos sus componentes.
import QtQuick 2.6
Definimos el rectángulo que contendrá el interfaz QML.
Rectangle {
width: parent.width;
height: parent.height
A continuación definimos un componente Component. Esto permite definir un componente propio que puede ser reutilizado. Muchas veces se definirá en un fichero aparte, con el fin de poder ser usado desde múltiples ficheros QML.
En este caso creamos un componente que denominamos delegado que nos permitirá pintar cada elemento que esté en la lista del modelo. Los delegados son un elemento del ListView y otras vistas que definen cómo se muestran elementos que contienen.
En el componente usamos los componentes posicionadores Column y Row. Se denominan posicionadores porque permiten definir cómo se van a colocar los elementos que contienen.
Component {
id: delegado
Item {
id: item
width: parent.width; height: 90
Row {
id: row
width: parent.width
anchors.margins: 10
spacing: 5
Image {
source: decoration; width: 160; height: 90
asynchronous: true
}
Un detalle importante: si queremos mejorar la usabilidad de nuestras aplicaciones debemos aprovechar todas las posibilidades que nos brinda QML para optimizar. En este caso usamos la propiedad asynchronous: true, para hacer que la carga de las imágenes sea en diferido, es decir, que se muestre el interfaz tan pronto como se cree y que las imágenes se vayan cargando en segundo plano, a fin de no paralizar el interfaz al usuario final.
Column {
width: parent.width - 260
Text {
text: display;
color: item.ListView.isCurrentItem ? "red" : "black"
font.bold: true
}
Text {
width: parent.width
text: "<u>Lorem ipsum dolor sit amet</u>, consectetur adipisicing <b>elit</b>, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.";
wrapMode: Text.Wrap
color: item.ListView.isCurrentItem ? "red" : "black"
}
}
Column {
width: 100
Text {
text: fecha;
color: "black"
font.bold: item.ListView.isCurrentItem ? true : false
}
Text {
text: hora;
color: "black"
font.bold: item.ListView.isCurrentItem ? true : false
}
}
}
El componente MouseArea no permiten definir un área en el que el usuario podrá interaccionar. En este caso, cuando el usuario haga clic sobre el elemento llevaremos haremos que se seleccione.
Si el usuario hace doble clic, en ese caso no sólo llevamos la selección si no que emitimos una señal de activado. Veremos en la vista ListView como la señal de activado se envía para que la detecte Velneo y muestre un formulario correspondiente al registro seleccionado.
MouseArea {
id: mouseArea
anchors.fill: parent
focus: true
onClicked: {
listView.currentIndex = index
}
onDoubleClicked: {
listView.currentIndex = index
listView.itemActivated(index)
}
}
}
}
Creamos otro componente que será el que usemos para la selección (highlight). Es el que define cómo se pinta la selección de un elemento de la vista ListView. Además, le incluimos una animación.
Component {
id: seleccion
Rectangle {
width: parent.width; height: 90
color: "lightsteelblue"; radius: 5
y: listView.currentItem.y
Behavior on y {
SpringAnimation {
spring: 3
damping: 0.2
}
}
}
}
Por último definimos la vista ListView que definimos por medio de los componentes que hemos ido creando.
ListView {
id: listView
anchors.fill: parent
model: theListModel
objectName: "theListView"
Para que la vista se alimente del origen que viene de Velneo (la lista de registros de entrada), definimos el modelo theListModel como aquél que alimenta la vista usando el elemento model.
Además, para que esta lista pueda ser gestionada también desde Velneo la definiremos como un objeto y le daremos el nombre theListView: objectName: “theListView”. En un objeto QML podemos tener muchas vistas, pero ésta será la que se gestione desde Velneo.
Para que las señales de Activado y Cambio de selección se envíen a Velneo, además de asignarles el nombre de objeto debemos definirlas en la vista que queremos que las dispare. Podemos gestionar desde Velneo el cambio de selección con la señal correspondiente y lanzar un evento. La señal de activado permite mostrar el formulario correspondiente al registro en curso que esté definido en el objeto QML.
signal itemActivated(int index)
signal selectionChanged(int index)
Tendremos que gestionar qué registro es el seleccionado y lanzar la señal correspondiente. Por ejemplo, en este caso, queremos que cada vez que se cambie la selección en el interfaz, este cambio de selección quede reflejado en la vista. Para ello usamos la señal de QML onCurrentIndexChanged que se dispara cuando hay un cambio para lanzar hacia Velneo la señal selectionChanged.
onCurrentIndexChanged:
{
listView.selectionChanged( listView.currentIndex )
}
El delegado, como habíamos comentado antes, permite definir la forma en que se mostrará cada elemento de la lista. En este caso hacemos uso de un componente previamente definido. Podríamos programarlo aquí, pero es aconsejable encapsular el código y dividirlo para que sea más sencillo y reutilizable.
delegate: delegado
De igual forma hemos hecho la definición de la selección (highlight), en la que indicamos que hacemos uso del componente creado anteriormente.
highlight: seleccion
highlightFollowsCurrentItem: false
focus: true
}
}
Esta vista funciona de igual modo que ListView, pero posiciona los elementos en un casillero, del que podemos gestionar orientación, etc.
A efectos prácticos, podemos sustituir uno por otro y configurar las características propias de de cada vista, sin necesitar realizar más cambios ver la misma lista de otra forma.
Por tanto, para aprovechar mejor el ejemplo, hemos incluido la sincronización de un GridView con un ListView que usaremos para mostrar un único elemento de la lista, haciendo una transición animada desde el GridView al elemento seleccionado que será visible en el ListView.
import QtQuick 2.6
Rectangle {
id:root
width: parent.width
height: parent.height
color: "black"
Aquí definimos el delegado, es decir, cómo se pintará cada elemento de la lista en el GridView.
Usaremos componentes Item, Row, Column, etc., para definir y posicionar los distintos elementos dentro de la celda.
Component {
id: delegado
Item {
width: 100
height: 100
Image {
source: decoration
width: parent.width
height: parent.height
fillMode: "Stretch"
opacity: 0.5
asynchronous: true
}
Text{ text: display; color: "white" }
MouseArea {
anchors.fill: parent
focus: true
onClicked: {
detalle.currentIndex = index
root.state = "vistaDetalle"
}
}
}
}
Aquí definimos el delegado del detalle, es decir, cómo se pintará cada elemento de la lista en el ListView. En realidad, únicamente se mostrará en pantalla uno de los elementos.
Usaremos componentes Grid (no debemos confundir GridView que gestiona una lista de registros, frente a Grid que gestiona una serie de elementos), Row, Column, etc., para definir y posicionar los distintos elementos dentro de la lista.
Component {
id: detalleDelegado
Grid {
id: detalleDelegadoGrid
rows: 3
spacing: 20
width: 500
Row {
Image {
source: decoration
asynchronous: true
width: 320
fillMode: Image.PreserveAspectFit
smooth: true
MouseArea {
id: mouseAreaImage
anchors.fill: parent
focus: true
onClicked: {
listaGrid.currentIndex = index
listaGrid.itemActivated(index)
}
}
}
Column {
Text {
text: display
font.pointSize: 24
color: "white"
}
Text {
text: fecha
font.pointSize: 18
color: "white"
}
Text {
text: hora
font.pointSize: 14
color: "white"
}
}
}
Row {
Text {
text: display
font.pointSize: 8
wrapMode: "Wrap"
color: "white"
}
}
En la última fila incluimos dos componentes que definimos como un rectángulo con un texto. Estos componentes los usaremos como botones que nos permitirán volver a la vista anterior o ver el registro en un formulario.
Row {
width: 300
anchors.bottom: parent.bottom
Rectangle {
id: rectangle1
width: 80
height: 25
color: "black"
border.color: "white"
border.width: 2
radius: 10
anchors.left: parent.left
Text {
id: text1
text: "Volver"
anchors.horizontalCenter: parent.horizontalCenter
anchors.verticalCenter: parent.verticalCenter
font.pointSize: 10
font.bold: true
color: "white"
}
Para cambiar qué visualización usaremos, el casillero GridView o la lista de un único elemento con ListView, usaremos state que nos permiten configurar estados para un elemento. Por medio de un elemento MouseArea definimos que si el usuario hace clic sobre un elemento del GridView, deje de estar en el estado Detalle que, como veremos más adelante, define que se vea en el ListView.
MouseArea {
anchors.fill: parent
focus: true
onClicked:
{
root.state = "";
}
}
}
Rectangle {
id: rectangle2
width: 80
height: 25
color: "black"
border.color: "white"
border.width: 2
radius: 10
anchors.right: parent.right
Text {
id: text2
text: "Ver"
anchors.horizontalCenter: parent.horizontalCenter
anchors.verticalCenter: parent.verticalCenter
font.pointSize: 10
font.bold: true
color: "white"
}
}
Y por medio de otro MouseArea definimos que el usuario vea el formulario del registro correspondiente, usando la señal de Activado.
MouseArea {
id: mouseAreaText
anchors.fill: parent
focus: true
onClicked: {
listaGrid.currentIndex = index
listaGrid.itemActivated(index)
}
}
}
}
}
}
Una vez definido el delegado, vamos a definir cómo se muestra la vista GridView.
GridView {
id: listaGrid
model: theListModel
delegate: delegado
Definimos además el modelo, theListModel para que se alimente a partir del proceso de carga en Velneo, además de indicar que el delegado para pintar cada elemento es el que hemos definido anteriormente: delegado.
width: root.width
height: root.height
cellWidth:110
cellHeight: 110
Definimos el tamaño de las celdas y además configuramos la propiedad objectName y la emisión de las señales para esta vista, que será la que muestre el formulario.
objectName: "theListView"
signal itemActivated(int index)
signal selectionChanged(int index)
highlightFollowsCurrentItem: false
onCurrentIndexChanged:
{
listaGrid.selectionChanged( listaGrid.currentIndex )
}
}
A continuación definimos la vista ListView que nos permitirá mostrar el elemento seleccionado. También se carga con el modelo de origen del objeto QML theListModel, pero en este caso se pinta con el delegado correspondiente detalleDelegado, que mostrará en pantalla únicamente el registro seleccionado.
ListView{
id: detalle
model: theListModel
delegate: detalleDelegado
opacity: 0
}
Ahora definimos los estados. En estado vistaDetalle pasaremos de ver la vista GridView al ListView con un único elemento. Si pasamos al estado anterior “”, entonces volveremos a ver la vista GridView.
states: [
State {
name: "vistaDetalle"
PropertyChanges {
target: listaGrid
x: -root.width
}
}
]
Aprovechamos para añadir un efecto por medio de la propiedad transitions que nos permite configurar la forma en que se pasa de una vista a otra, aprovechando para ello la diversidad de efectos de que nos dota QML.
transitions: [
Transition {
from: ""
to: "vistaDetalle"
NumberAnimation {
properties: "x"
easing.type: "OutBounce"
}
PropertyAnimation {
target: detalle
property: "opacity"
to: 1
}
},
Transition {
from: "vistaDetalle"
to: ""
NumberAnimation {
properties: "x"
easing.type: "OutSine"
duration: 250
}
PropertyAnimation {
target: detalle
property: "opacity"
to: 0
}
}
]
}
Última actualización 2yr ago